
0 GOTO44!
    ## FARBFRA 5 ##


1 GOTO78!Bei Programmabbruch z.B. nach fehlerhaftem Laden GOTO1 eing.!
2 INK1:IFW=39THENN$=STRING$(32,CHR$(128)):ELSEN$=STRING$(32,"$"):GOTO6
4 FORA=0TO31:PRINTAT(A,0);N$;:NEXT:INK7:RETURN:!KC85
6 FORA=0TO31:PRINTAT(A,0);N$:NEXT:INK7:RETURN:!Z1013
8 IFW=31THENINPUT"";N$
10 CLS:PRINTF$(10)
12 N$="":PRINT:INPUT" Name?         ";N$
14 IFN$>""THENCSAVE*""+N$;F$:GOTO10:ELSE70
16 CLS:N$="":INPUT" Name:         ";N$
18 IFN$>""THENF$(0)="":CLOAD*""+N$;F$:ELSE70
20 CLS:PRINTN$;"       ":PRINTF$(10):IFW=39THENDOKE17,0
22 FORA=0TO9:FORP=1TOLEN(F$(A)):F=USR(ASC(MID$(F$(A),P,1))):NEXT:NEXT:GOTO8
24 CLS:M=0:INPUT"X1,X2 =";R,A:S=(A-R)/64
26 PRINT:INPUT"Y1,Y2 =";B,Y:T=(Y-B)/64:PRINT
28 INPUT"Zyklen?";M:M=INT(ABS(M)):IFM=0THENN$="":GOTO70
30 N$=CHR$(13):F$(10)="X1,X2 = "+STR$(R)+","+STR$(A)+N$+"Y1,Y2 = "
32 F$(10)=F$(10)+STR$(B)+","+STR$(Y)+N$+"Z ="+STR$(M):IFW=39THENDOKE17,0
34 GOSUB2:FORA=0TO9:F$(A)="":NEXT:Y=Y+T:FORI=0TO63:X=R-S:Y=Y-T
36 FORJ=1TON:F=0:FORK=8TO1STEP-7:X=X+S:A=-Y:B=X:P=0
38 FORZ=0TOM:C=A*B:A=A*A:B=B*B:IFA+B>4THENP=K*(Z-INT(Z/8)*8):Z=M
40 A=A-B-Y:B=C+C+X:NEXT:F=F+P:NEXT:A=INT(I/7)
42 F$(A)=F$(A)+CHR$(USR(F+N)):NEXT:NEXT:BEEP:BEEP:GOTO8
44 FORA=1TO19:READB,T:IFPEEK(-2244)<>BTHENNEXT:ELSEA=19:NEXT
46 IFT=111THENPRINT"Z1013,KC85/2,3 o. 4 wurde nicht erkannt!"
48 IFT=111THENPRINT"48 T=13 oder 21/31/41 f}r Z1013/KC85/2,3,4":END
50 IFT>20THEN54:ELSECLEAR5000,32639:RESTORE98:FORA=32640TO32767
52 READB:POKEA,B:NEXT:A=31:B=DEEK(11012):DOKE11012,32640:GOTO62
54 FORA=0TO7:POKEA,240:NEXT:VPOKE14252,0:VPOKE14253,0:!VPOKE KC85
56 IFT>40THENRESTORE92:FORA=10TO64:READB:POKEA,B:NEXT:GOTO60
58 RESTORE88:FORA=10TO38:READB:POKEA,B:NEXT
60 CLEAR5000:A=39:B=DEEK(772):DOKE772,10
62 C=0: X=0:Y=0:Z=0:P=0:F=0:K=0:M=0:N=32:S=0:T=0:J=0:I=0:R=0:W=A:U=B
64 WINDOW0,31,0,W:PAPER1:INK7:CLS:!U puffert USR-Adresse
66 WINDOW0,31,W-7,W:CLS:PRINT:PRINT"GERRiT'sFARBFRA 8.12.'13"
68 N$="":WINDOW6,31,W-7,W:IFW=39THENGOSUB2
70 CLS:PRINT"F=FRAK- TAL":PRINT:PRINT"L=LADEN ":PRINT"S=SAVEN "
72 PRINT"H=HILFE ":PRINT"E=ENDE":PRINT:INPUT"Wahl:";N$
74 IFN$="F"GOTO24:ELSEIFN$="L"GOTO16:ELSEIFN$="S"GOTO10
76 IFN$="H"GOTO116:ELSEIFN$<>"E"THEN70
78 IFW=31THENDOKE11012,U:PRINT:PRINT"Goodbye!":!Z1013
80 IFW=39THENDOKE772,U:PRINT:PRINT"Tsch}~!":VPOKE14253,254:!KC85
82 PAUSE20:WINDOW0,31,0,W:CLS:END
84 DATA54,13,237,13.2,44,1,24,21,62,22,216,24,48,23.1,254,23.3,178,31
86 DATA247,34,209,39,125,41,76,42,17,42.2,61,43,201,44,35,50,208,63
88 DATA205,111,201,205,24,240,33,0,0,62,168,180,103,123,214,32,119
90 DATA35,34,17,0,205,27,240,175,67,195,177,208:!ab hier KC85/4
92 DATA205,111,201,205,24,240,33,0,0,203,252,221,126,1,87,238,2,211,132
94 DATA123,214,32,119,35,119,35,119,35,119,122,211,132,205,27,240,175
96 DATA67,17,253,128,25,203,108,40,4,17,4,224,25,34,17,0,195,177,208
98 DATA205,111,12,67,175,197,205,177,19,17,63,63,62,64,28,187:!Z1013
100 DATA32,8,30,0,20,186,32,2,22,0,241,214,32,245,213,230,8
102 DATA205,173,127,209,28,237,83,138,127,241,230,1,40,2,203
104 DATA251,203,19,8,175,203,19,203,58,23,203,58,203,27,203,58
106 DATA203,27,203,58,203,27,23,245,33,0,236,25,126,235,33,255
108 DATA127,1,16,0,237,185,35,241,60,254,3,32,2,62,8,8,56,5,8
110 DATA47,165,24,2,8,181,111,126,235,119,201,0,0,32,176,177
112 DATA182,178,184,181,189,179,180,185,188,183,187,186,255
114 !mit Dank an Frank Ludwig f}r den KC-Maschinencode
116 WINDOW0,31,0,W:CLS:PRINT
118 PRINT"FARBFRA - Fraktale in 8 Farben am KC85"
120 PRINT:PRINT"F-Fraktal":PRINT"---------"
122 PRINT"Hiermit starten Sie eine":PRINT"Apfelm{nnchen-Berechnung."
124 PRINT"Die Koordinaten X1,X2,Y1,Y2":PRINT"sind paarweise einzugeben."
126 PRINT"Nun noch die Zykluszahl,":PRINT"z.B. 50, und es geht los."
128 PRINT"Dr}cken Sie dort nur Enter,":PRINT"gelangen Sie zur}ck ins Men}."
130 PRINT"Wollen Sie das Bildberechnen":PRINT"stoppen, geht das nur mit"
132 PRINT"der BRK-Taste. Fortsetzen":PRINT"ist dann noch mit CONT m|glich."
134 PRINT"Zum Schlu~ ist das Bild durch":PRINT"Namenseingabe speicherbar."
136 PRINT"Das wiederholt sich":PRINT"bis nur <Enter> gedr}ckt wird."
138 PRINT:PRINT:PRINTTAB(25);:INPUT"<ENTER>";N$
140 CLS:PRINT:PRINT"L-Laden":PRINT"-------"
142 PRINT"Richtig, damit holen Sie ein":PRINT"gespeichertes Fraktal"
144 PRINT"zur}ck auf den Bildschirm.":PRINT"Geben Sie einen Namen ein"
146 PRINT"und starten Sie das Band.":PRINT"Wiederum kann mit Namen"
148 PRINT"gespeichert werden."
150 PRINT:PRINT:PRINT"E-Ende":PRINT"------"
152 PRINT"Irgendwann will man ja auch":PRINT"wieder was anderes tun."
154 PRINT:PRINT:PRINTTAB(25);:INPUT"<ENTER>";N$:CLS:PRINT
156 PRINT"Nun noch einige interessante":PRINT"Bildkoordinaten:":PRINT
158 PRINT"Eine }bersicht liefern":PRINT"X1,X2=-2,2 Y1,Y2=-2,2 Z=25"
160 PRINT"Etwas gr|~er wird es mit":PRINT"X1,X2=-1.5,1.5 Y1,Y2=-1,2 Z=50"
162 PRINT"Etwas f}rs Auge ist dann":PRINT"X1,X2=0.128,0.134"
164 PRINT"Y1,Y2=0.739,0.745 Z=300":PRINT
166 PRINT"Gehen Sie auf Endeckungsreise":PRINT"und finden Sie viele"
168 PRINT"sch|ne Bildausschnitte.":PRINT:PRINT"Viel Freude w}nscht"
170 PRINT"GERRiTsoft@gmx.de       ";:INPUT"<ENTER>";N$:GOTO64
172 !Dieses Programm darf ge{ndert werden. Teile, auch der MC
174 !duerfen unter Angabe der Quelle verwendet werden.
176 !Aenderungen bei Weitergabe bitte kommentieren.
